Color Images

As with black and white PostScript, images may be output with 1, 2, 4, or 8 bits, yielding 1, 2, 16, or 256 possible colors. In addition, images are either pseudo-color or true-color. A pseudo-color image is a two dimensional image, each pixel of which is used to index the color table, thereby obtaining an RGB value for each possible pixel value. Pseudo-color images are similar to those displayed using the workstation monitor.

Note: in the case of pseudo-color images of fewer than 8 bits, the number of columns in the image should be an exact multiple of the number of pixels per byte (i.e., when displaying 4 bit images the number of columns should be even, and 2 bit images should have a column size that is a multiple of 4). If the image column size is not an exact multiple, extra pixels with a value of 255 are output at the end of each row. This causes no problems if the color white is loaded into the last color table entry, otherwise a stripe of the last (index number 255) color is drawn to the right of the image.

True-Color Images

A true-color image consists of an array with three dimensions, one of which has a size of three, containing the three color components. It may be considered as three two dimensional images, one each for the red, green and blue components. For example a true-color n by m element image can be ordered in three ways: pixel interleaved (3, n , m ), row interleaved ( n , 3, m ), or image interleaved ( n , m , 3). By convention the first color is always red, the second green, and the last is blue.

True-color images are also routed through the color tables. The red color table array contains the intensity translation table for the red image, and so forth. Assuming that the color tables have been loaded with the vectors R , G , and B , a pixel with a color value of ( r , g , b ) is displayed with a color of ( R _r , G _g , B _b ). As with other devices, a color table value of 255 represents maximum intensity, while 0 indicates an absence of the color. To pass the RGB pixel values without change, load the red, green and blue color tables with a ramp with a slope of 1.0:

TVLCT, INDGEN(256), INDGEN(256), INDGEN(256)

or with the LOADCT procedure:

LOADCT, 0 ; Load standard black/white table.

Use the TRUE keyword to the TV and TVSCL procedures to indicate that the image is a true-color image and to specify the dimension over which color is interleaved. A value of 1 specifies pixel interleaving, 2 is row interleaving, and 3 is image interleaving. The following example writes a 24-bit image, interleaved over the 3rd dimension, to a PostScript file:

SET_PLOT, 'PS'

;Set the PostScript device to *8* bits per color, not 24:

DEVICE, FILE='24bit.ps', /COLOR, BITS=8

TV, [[[r]], [[g]], [[b]]], TRUE=3

DEVICE, /CLOSE

SET_PLOT, `mac' ; Return plotting to Macintosh windows.

Image Background Color

Images that are displayed with a black background on a monitor frequently look better if the background is changed to white when displayed with PostScript. This is easily done with the statement:

a(WHERE(a EQ 0B)) = 255B

Using the XOFFSET and YOFFSET Keywords

Often, IDL users are confused by the use of the XOFFSET and YOFFSET keywords to the PostScript DEVICE routine. These keywords control the position of IDL plots on the page. XOFFSET specifies the "X" position of the lower left corner of the output generated by IDL. This offset is always taken relative to the lower left-hand corner of the page when viewed in portrait orientation. YOFFSET specifies the "Y" position of the lower left corner of the output generated by IDL. This offset is also taken relative to the lower left-hand corner of the page when viewed in portrait orientation.

This diagram shows how the XOFFSET and YOFFSET keywords are interpreted by the PostScript device in the Portrait (left) and Landscape (right) modes. Note that the landscape plot uses the same origin for determining the effect of the XOFFSET and YOFFSET keywords, but that the output is rotated 270 degrees clockwise. shows how the XOFFSET and YOFFSET keywords are interpreted. The page on the left shows an IDL plot printed in "portrait" orientation. Note that the X and Y offsets work just as we expect them to--increasing the XOFFSET moves the plot to the right and increasing the YOFFSET moves the plot up the page. The page on the right shows an IDL plot printed in "landscape" orientation. Here, the X and Y offsets are still taken relative to the same points even though the orientation of the plot has changed. This happens because IDL moves the origin of the plot before rotating the PostScript coordinate system 270 degrees clockwise for the landscape plot.

Note also that the XOFFSET and YOFFSET keywords have no effect when you generate ENCAPSULATED PostScript output.

Encapsulated PostScript Output

Another form of PostScript output is Encapsulated PostScript. This is the format used to import PostScript files into page layout and desktop publishing programs. An Encapsulated PostScript (EPS) file is similar to a regular PostScript file except that it contains only one page of PostScript output contained in a "bounding box" that is used to tell other programs about the size and aspect ratio of the encapsulated image.

Most of the time, output from IDL to an EPS file is properly scaled into the EPS bounding box because commands such as PLOT take full advantage of the plotting area made available to them. Sometimes, however, the default bounding box is inappropriate for the image being displayed.

As an example, suppose you have an image that is narrow and tall that, when TV'ed to an IDL window, fills only a small portion of the plotting window. Similarly, when output to an EPS file, this image will only fill a small portion of the bounding box. When the resulting EPS file is brought into a desktop publishing program, it becomes very hard to properly scale the image since the aspect ratio of the bounding box bears no relation to the aspect ratio of the image itself.

To solve this problem, use the XSIZE and YSIZE keywords to the DEVICE procedure to make the bounding box just large enough to contain the image. Since IDL uses a resolution of 1000 dots per centimeter with the PostScript device, the correct XSIZE and YSIZE (in centimeters) can be computed as:

• XSIZE = Width of image in pixels/1000.0 pixels per cm
• YSIZE = Height of image in pixels/1000.0 pixels per cm

The following IDL procedure demonstrates this technique. This procedure reads an X Windows Dump file and writes it back out as a properly-sized, 8-bit-color Encapsulated PostScript file:

PRO XWDTOEPS, filename

array = READ_XWD(filename, r, g, b); Read the XWD file. Pixel intensity information is stored in the variable `array'. Values to reconstruct the color table are stored in `r', `g', and `b'.

TVLCT, r,g,b ; Reconstruct the color table.

TV, array ; Display the image in an IDL window.

s = SIZE(array) ; Find the size of the picture. The width of the picture (in pixels) is stored in s[1]. The height of the picture is stored in s[2]:

fl = STRLEN(filename) ; Take the `xwd' (for X Windows Dump) extension off of the old filename and replace it with `eps'.

filename = STRMID(filename, 0, fl-4)

filename = filename + '.eps'

PRINT, 'Making file: ', filename

PRINT, s

SET_PLOT, 'ps' ; Set the plotting device to PostScript.

DEVICE, /ENCAPSUL, BITS_PER_PIXEL=8, /COLOR, $

   FILENAME=filename, XSIZE=S[1]/1000., $

   YSIZE=S[2]/1000. ; Use the DEVICE procedure to make the output encapsulated, 8 bits, color, and only as wide and high as it needs to be to contain the XWD image:

TV, array ; Write the image to the file.

DEVICE, /CLOSE ; Close the file.

SET_PLOT, 'x' ; Return plotting to X Windows.

END

Multiple Plots on the Same Page

To put multiple plots on the same PostScript page, use the !P.MULTI system variable (described in more detail in ). !P.MULTI is a 5-element integer array that controls the number of rows and columns of plots to make on a page or in a graphics window.

The first element of !P.MULTI is a counter that reports how many plots remain on the page. The second element of !P.MULTI is the number of columns per page. The third element is the number of rows per page.

For example, the following lines of code create a PostScript file, multi.ps , with 6 different plots arranged as 2 columns and 3 rows:

SET_PLOT, 'PS' ; Set plotting to PostScript.

DEVICE, FILENAME='multi.ps' ; Set the filename.

!P.MULTI = [0, 2, 3] ; Make IDL's plotting area hold 2 columns and 3 rows of plots.

A = FINDGEN(10) ; Create a simple dataset.

PLOT, A ; Make 6 different plots.

PLOT, SIN(A)

PLOT, COS(A)

PLOT, TAN(A)

PLOT, TANH(A)

PLOT, SINH(A)

DEVICE, /CLOSE ; Close the file.

SET_PLOT, 'win' ; Return plotting to Windows.

!P.MULTI = 0 ; Reset plotting to 1 plot per page.

The resulting file produces a set of plots as shown in Multiple plots on a single page produced by setting the !P.MULTI system variable. .